AX 2012 Export Data with Outbound ports

I've recently made some tests with AIF (Application Integration Framework), inbound ports and outbound ports.
I had never used AIF before AX 2012 and this is a great tool once you understand how it works.
MSDN explains the subject quite correctly : Services and Application Integration Framweork 2012

At the beginning, I did not understand the concept of outbound port. SoI decided to take an interest in it. I've known web services for a long time now so I could correctly understand the "inbound port" concept; a service is "listening" at a specific "port", ready to execute your method with input parameters.
But what for outbound ports ? There is no socket "port" to pull out data....

Outbound ports are not related with web services or network at all (talking about WCF, bindings and endpoints). You can use it in order to retreive data from Dynamics AX and send the results to either a file or a message queue (MSMQ).


The following post will show a summary of the steps I followed in order to export customers in several XML files into a directory on the AOS server.

1. I create an outbound port specifying "File system adapter" as adapter.
   You can limit it to a specific company if you want
   In the operations I choose : CustCustomerService.read
   
   This service operation will be used to read a customer from AX by specifying an account number.
   The output result of the operation will be the customer itself.
   
2. I create a new folder on the AOS side (in the example C:\AIFOutputTemp).
   Don't forget to give the correct write access rights for the user executing your AOS Service.
   The AOS will need write access to create the file.
3. I specify the newly created folder in the URI of the outbound port.
4. I save the outbound port and I activate it.
5. I create a new job to post some customer in the AIF Queue :
   
   

   static void AIF_SendCustomer(Args _args)
   {
   
       AxdSendContext axdSendContext = AxdSendContext::construct();
       AifEntityKey aifEntityKey = AifEntityKey::construct();
       Map keyData;
       AifConstraintList aifConstraintList = new AifConstraintList();
       AifConstraint aifConstraint = new AifConstraint();
   
       CustTable       custTable;
       ;
   
       custTable = CustTable::find("<CUSTACCOUNT>");
      
       keyData = SysDictTable::getKeyData(custTable);
   
       aifEntityKey.parmTableId(custTable.TableId);
       aifEntityKey.parmRecId(custTable.RecId);
       aifEntityKey.parmKeyDataMap(keyData);
   
       axdSendContext.parmXMLDocPurpose(XMLDocPurpose::Original);
       axdSendContext.parmSecurity(false);
   
       aifConstraint.parmType(AifConstraintType::NoConstraint) ;
       aifConstraintList.addConstraint(aifConstraint) ;
   
       AifSendService::submitDefault(
           classnum(CustCustomerService),
           aifEntityKey,
           aifConstraintList,
           AifSendMode::Async,
           axdSendContext.pack());
   
   }

6. Once this code is executed, a new record will be created in the AIF Queue manager.
   
   You can reach the queue manager with the following path :
   System Administration > Periodic > Services and Application Integration Framework > Queue manager
   
   Status will be ready and you will see the document service operation involved.
   
   
   
7. Now the instructions are created with correct parameters. You can either setup a batch system tha will automatically execute the following method, or you can simply execute it manually.
   There is an explanation of this at msdn : Configuring batch jobs for AIF
   

   AifOutboundProcessingService = new AifOutboundProcessingService();

   AifOutboundProcessingService.run();

8. Once this method has been executed, you will be able to see the resulting newly created AIF message (XML result). For this, use the following menu : Document Log and View message
   
   
   
   
   
   
   


9. Once the message has been created, we can execute the following method :
   
   

   AifGatewaySendService = new AifGatewaySendService();

   AifGatewaySendService.run();

10. This operation will export the message to a physical XML file on the folder we specified in the outbound port.

 That's it for outbound ports.